Loop (registry)

Retrieves the contents of the specified registry subkey, one item at a time.

Loop Reg, KeyName , Mode

Parameters

Reg

The literal word Reg (case-insensitive). This cannot be a variable or expression.

KeyName

The full name of the registry key.

This must start with HKEY_LOCAL_MACHINE, HKEY_USERS, HKEY_CURRENT_USER, HKEY_CLASSES_ROOT, or HKEY_CURRENT_CONFIG (or the abbreviations for each of these, such as HKLM). To access a remote registry, prepend the computer name and a slash, as in this example: \\workstation01\HKEY_LOCAL_MACHINE

Mode

Zero or more of the following letters:

K: Include keys.
V: Include values. Values are also included if both K and V are omitted.
R: Recurse into subkeys. If R is omitted, keys and values within subkeys of Key are not included.

Remarks

A registry-loop is useful when you want to operate on a collection registry values or subkeys, one at a time. The values and subkeys are retrieved in reverse order (bottom to top) so that RegDelete can be used inside the loop without disrupting the loop.

The following variables exist within any registry-loop. If an inner registry-loop is enclosed by an outer registry-loop, the innermost loop's registry item will take precedence:

When used inside a registry-loop, the following functions can be used in a simplified way to indicate that the currently retrieved item should be operated upon:

When accessing a remote registry (via the KeyName parameter described above), the following notes apply:

• The target machine must be running the Remote Registry service.
• Access to a remote registry may fail if the target computer is not in the same domain as yours or the local or remote username lacks sufficient permissions (however, see below for possible workarounds).
• Depending on your username's domain, workgroup, and/or permissions, you may have to connect to a shared device, such as by mapping a drive, prior to attempting remote registry access. Making such a connection -- using a remote username and password that has permission to access or edit the registry -- may as a side-effect enable remote registry access.
• If you're already connected to the target computer as a different user (for example, a mapped drive via user Guest), you may have to terminate that connection to allow the remote registry feature to reconnect and re-authenticate you as your own currently logged-on username.
• For Windows Server 2003 and Windows XP Professional, MSDN states: "If the [registry server] computer is joined to a workgroup and the Force network logons using local accounts to authenticate as Guest policy is enabled, the function fails. Note that this policy is enabled by default if the computer is joined to a workgroup."
• For Windows XP Home Edition, MSDN states that "this function always fails". Home Edition lacks both the registry server and client, though the client can be extracted from one of the OS cab files.

See Loop for information about Blocks, Break, Continue, and the A_Index variable (which exists in every type of loop).

Related

Loop, Break, Continue, Blocks, RegRead, RegWrite, RegDelete, SetRegView

Examples

; Example: Delete Internet Explorer's history of URLs typed by the user:
Loop Reg, "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\TypedURLs"
    RegDelete

; Example: A working test script:
Loop Reg, "HKCU\Software\Microsoft\Windows", "R KV"  ; Recursively retrieve keys and values.
{
    if a_LoopRegType = "key"
        value := ""
    else
    {
        value := RegRead()
        if ErrorLevel
            value := "*error*"
    }
    Result := MsgBox(a_LoopRegName " = " value " (" a_LoopRegType ")`n`nContinue?",, "y/n")
}
Until Result = "No"

; Example: A working example to recursively search the entire
; registry for particular value(s).
RegSearch("Notepad")
return

RegSearch(Target)
{
    ContinueRegSearch := true
    Loop Reg, "HKEY_LOCAL_MACHINE", "KVR"
    {
        Gosub CheckThisRegItem
        if !ContinueRegSearch  ; It told us to stop.
            return
    }
    Loop Reg, "HKEY_USERS", "KVR"
    {
        Gosub CheckThisRegItem
        if !ContinueRegSearch  ; It told us to stop.
            return
    }
    Loop Reg, "HKEY_CURRENT_CONFIG", "KVR"
    {
        Gosub CheckThisRegItem
        if !ContinueRegSearch  ; It told us to stop.
            return
    }
    ; Note: I believe HKEY_CURRENT_USER does not need to be searched if HKEY_USERS is
    ; being searched.  Similarly, HKEY_CLASSES_ROOT provides a combined view of keys from
    ; HKEY_LOCAL_MACHINE and HKEY_CURRENT_USER, so searching all three isn't necessary.
    return

CheckThisRegItem:
    if A_LoopRegType = "KEY"  ; Remove these two lines if you want to check key names too.
        return
    RegValue := RegRead()
    if ErrorLevel
        return
    if InStr(RegValue, Target)
    {
        Result := MsgBox(Format("
        (
        The following match was found:
        {1}\{2}
        Value = {3}
        
        Continue?
        )", A_LoopRegKey, A_LoopRegName, RegValue),, "y/n")
        if Result = "No"
            ContinueRegSearch := false  ; Tell our caller to stop searching.
    }
    return
}